Re: New Presentation about Modern GWT Webapp Development

I added Gradle in the "Tools" page, enjoy 😊 

t.br...@gmail.com schrieb am Montag, 21. September 2020 um 18:52:56 UTC+2:

Fwiw, without plugin (Kotlin DSL):

val gwtOutputDir = file("$buildDir/gwtc/war")
tasks {
    val gwtCompile by registering(JavaExec::class) {
        val companionOutputDir = file("$buildDir/gwtc")
        val deployDir = file("$companionOutputDir/extra")
        val extraDir = deployDir
        val genDir = file("$companionOutputDir/gen") // XXX: useful?
        val workDir = file("$companionOutputDir/work")


        outputs.dir(gwtOutputDir).withPropertyName("outputDir")
        outputs.dir(deployDir).withPropertyName("deployDir")
        outputs.dir(extraDir).withPropertyName("extraDir")
        outputs.dir(genDir).withPropertyName("genDir")
        outputs.dir(workDir).withPropertyName("workDir")


        classpath = gwt
        maxHeapSize = "1g"
        main = "com.google.gwt.dev.Compiler"
        args(
            "-failOnError",
            "-XdisableCastChecking",
            "-XdisableClassMetadata",
            "-war", gwtOutputDir,
            "-deploy", deployDir,
            "-extra", extraDir,
            "-gen", genDir,
            "-workDir", workDir,
            "com.example.app.App"
        )


        doFirst {
            delete(gwtOutputDir, deployDir, extraDir, genDir)
        }
    }


    register<JavaExec>("run") {

        val workDir = file("$buildDir/gwt/codeserver")


        classpath = gwt
        maxHeapSize = "2g"
        main = "com.google.gwt.dev.codeserver.CodeServer"
        args(
            "-failOnError",
            "-launcherDir", gwtOutputDir,
            "-workDir", workDir,
            "com.example.app.App"
        )


        doFirst {
            delete(gwtOutputDir)
            mkdir(workDir)
        }
    }


    integrationTest {
        val warDir = file("$buildDir/gwt/www-test")
        val workDir = file("$buildDir/gwt/work")
        outputs.dir(warDir).withPropertyName("warDir")
        outputs.dir(workDir).withPropertyName("workDir")


        isScanForTestClasses = false
        include("**/*Suite.class")


        maxHeapSize = "1g"
        systemProperty("gwt.args", """-ea -draftCompile -batch module -war "$warDir" -workDir "$workDir" -runStyle HtmlUnit:FF38""")

    }
}

On Monday, September 21, 2020 at 2:04:38 PM UTC+2, Michael Joyner wrote:

There is also this jiakuan fork of the steffenschaefer plugin:

https://github.com/jiakuan/gwt-gradle-plugin

Maintenance of the fork is active.

On 9/21/20 6:55 AM, Joker Joker wrote:

Lofi,

I tried 3 plugins and this one (esoco) is the best one among them. 2 of them are abandoned. The plugin from esoco is the only one mantained at the moment.

https://github.com/steffenschaefer/gwt-gradle-plugin (abandoned)

https://github.com/Putnami/putnami-gradle-plugin (abandoned)

https://github.com/esoco/gwt-gradle-plugin  (active)

Putnami was my choise before it was abandoned.

Now I use esoco gradle plugin on 2 my large production projects and on on several gwt libraries.

пятница, 18 сентября 2020 г. в 00:39:06 UTC+4, jumanor:

Gran trabajo, muchas gracias.

great job!

El lunes, 11 de mayo de 2020 a las 16:01:56 UTC-5, lofid...@gmail.com escribió:

Hi All,

if you need a presentation about modern GWT development as an introduction, just take a look at this:

https://bit.ly/gwtintropresentation

I also added this presentation in the Modern GWT Padlet: https://bit.ly/GWTIntroPadlet

Have fun,

Lofi

--
You received this message because you are subscribed to the Google Groups "GWT Users" group.

To unsubscribe from this group and stop receiving emails from it, send an email to google-web-toolkit+unsub...@googlegroups.com.

To view this discussion on the web visit https://groups.google.com/d/msgid/google-web-toolkit/e0ed6d1f-5962-4d23-b3d4-5354270b5f79n%40googlegroups.com.

--
You received this message because you are subscribed to the Google Groups "GWT Users" group.
To unsubscribe from this group and stop receiving emails from it, send an email to google-web-toolkit+unsubscribe@googlegroups.com.
To view this discussion on the web visit https://groups.google.com/d/msgid/google-web-toolkit/356d1059-a9bf-4ab1-ac6f-ce6a12135c99n%40googlegroups.com.